Мигающий экран на Assembler

; fasm-code
; мигающий красный экран
;------------------------
org  100h
jmp  start

tRed    db   'Second 1-9: $'
slp     dw   0     ; счётчик

start:  mov   ax,3            ; мода 80х25/16
        int   10h
        push  0b800h 0
        pop   fs es           ; FS = bios, ES = видеобуфер

        mov   ah,9            ; мессага
        mov   dx,tRed
        int   21h
        mov   ah,1            ; ввод секунд 0-9
        int   21h
        and   ax,0fh          ; символ-в-число
        shl   ax,4            ; *16 для тиков
        mov   [slp],ax        ; запомнить счётчик!

        mov   ah,2            ; скрыть курсор
        mov   dx,1a01h
        int   10h

        mov   bx,0cdbh        ; 0Сh = красный, DBh = квадрат.

@fill:  mov   cx,80*25        ; символов на экране
        mov   ax,bx           ;  ..что выводить
        xor   di,di           ;    ..куда
        rep   stosw           ;      ..вывод на экран!
        call  Sleep           ; спать!

        mov   cx,80*25        ; проснуться и повторить
        mov   al,' '          ; только не квадрат, а пробел (очистить экран)
        xor   di,di
        rep   stosw
        call  Sleep

        mov   ah,6            ; проверить буфер клавы..
        mov   dl,-1
        int   21h
        cmp   al,13           ; Enter?
        jnz   @fill           ; нет - повторить..

@exit:  mov   ah,4ch
        int   21h             ; на выход!

;--- Таймер ---------
Sleep:  mov   bp,word[fs:46ch]   ; считать тики с биоса
        add   bp,[slp]           ; прибавить задержку
@wait:  mov   dx,word[fs:46ch]   ; ещё-раз считать
        cmp   dx,bp              ;
        jbe   @wait              ; если разница меньше..
        ret                      ; иначе: вернуться!