Последние записи

Интенсив по Python: Работа с API и фреймворками 24-26 ИЮНЯ 2022. Знаете Python, но хотите расширить свои навыки?
Slurm подготовили для вас особенный продукт! Оставить заявку по ссылке - https://slurm.club/3MeqNEk

Online-курс Java с оплатой после трудоустройства. Каждый выпускник получает предложение о работе
И зарплату на 30% выше ожидаемой, подробнее на сайте академии, ссылка - ttps://clck.ru/fCrQw

30th
Мар

Передача процедуры в процедуру через Pointer

Posted by maloy under Delphi, Архив

Вадим Буренков

Возник такой вопрос:
есть процедура высокоточного таймера:

Код:

function timeSetEvent(uDelay, uResolution: UINT; lpTimeProc: Pointer; dwUser: DWORD; 
fuEvent: UINT): UINT; stdcall; external 'winmm.dll';

При этом параметры такие:

Цитата:

Здесь uDelay — необходимый период срабатывания таймера (в мс); uResolution — разрешение таймера (значение 0 означает, что события срабатывания таймера будут возникать с максимально возможной частотой; в целях снижения нагрузки на систему вы можете увеличить это значение); lpTimeProc — адрес процедуры обратного вызова; dwUser — произвольное число, которое передается процедуре обратного вызова и которым программист может распоряжаться по своему усмотрению; fuEvent — параметр, управляющий периодичностью возникновения события таймера: TIME_ONESHOT (0) — событие возникает только один раз через uDelay миллисекунд; TIME_PERIODIC (1) — события возникают периодически каждые uDelay мс.

Получается что процедура передается в процедуру как Pointer (lpTimeProc )
Как мне сделать чтоб я мог аналогичным образом передать Pointer указатель на процедуру в свою процедуру, а потом запускать ее при надобности? (надеюсь понятно объяснил ).

Daramant

Вот такие варианты:

Код:


unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

type
  TProc = procedure;
  TProcWithParams = procedure(params: array of const);

var
  Form1: TForm1;

implementation

{$R *.dfm}

// процедура без параметров

procedure Proc;
begin
  ShowMessage('Proc is called!');
end;

procedure MainProc1(ProcPtr: Pointer);
begin
  // просто так вызвать указатель не получилось, его нужно привести к типу процедуры,
  // как сделано в MainProc3
  //ProcPtr^;
end;

procedure MainProc2(Proc: TProc);
begin
  Proc;
end;

procedure MainProc3(ProcPtr: Pointer);
begin
  TProc(ProcPtr);
end;

// процедура с параметрами

procedure ProcWithParams(params: array of const);
begin
  ShowMessage(Format('Params: p1=%d, p2=%d, p3=%s', params));
end;

procedure MainProc4(ProcWithParams: TProcWithParams; params: array of const);
begin
  ProcWithParams(params);
end;

procedure MainProc5(ProcWithParamsPtr: Pointer; params: array of const);
begin
  TProcWithParams(ProcWithParamsPtr)(params);
end;

// вызов процедур

procedure TForm1.Button1Click(Sender: TObject);
begin
  MainProc1(@Proc); // не работает
  MainProc2(Proc);
  MainProc3(@Proc);

  MainProc4(ProcWithParams, [1, 2, '123']);
  MainProc5(@ProcWithParams, [5, 67, 'qweqwe']);
end;

end.

тема на форуме от 2009 года