Последние записи

made in programmersforum 5

Интенсив по Python: Работа с API и фреймворками 24-26 ИЮНЯ 2022. Знаете Python, но хотите расширить свои навыки?
Slurm подготовили для вас особенный продукт! Оставить заявку по ссылке - https://slurm.club/3MeqNEk

Online-курс Java с оплатой после трудоустройства. Каждый выпускник получает предложение о работе
И зарплату на 30% выше ожидаемой, подробнее на сайте академии, ссылка - ttps://clck.ru/fCrQw

8th
Май

Функция, для разбивки строки с разделителями в stringlist

Posted by Chas under Delphi

Необходимо из xls файла сделать xml.Сам xls представляет собой довольно большую таблицу,расписание занятий.Пробовал обращаться к таблице через Variant,но дело в том,что программа должна быть универсальной для любого количества столбцов и строк,а также любой разметки.Поэтому пришлось сохранять как Текстовый документ(с разделителем табуляцией).Подскажите как мне вытащить данные и записать их в группы,по столбцам.

GunSmoker
Например, так (режем строчку, используя TStrings):

procedure Tokenize(const ASource: String; const ADelimiter: Char; const AResult: TStrings);

var

  SavedDelimiter: Char;

  SavedQuoteChar: Char;

  SavedStrictDel: Boolean;

  DelimitedText: String;

begin

  SavedDelimiter := AResult.Delimiter;

  SavedQuoteChar := AResult.QuoteChar;

  SavedStrictDel := AResult.StrictDelimiter;

  try

    AResult.Delimiter := ADelimiter;

    AResult.QuoteChar := '"';

    AResult.StrictDelimiter := True;
    DelimitedText := AResult.QuoteChar + StringReplace(ASource, ADelimiter, AResult.QuoteChar + ADelimiter + AResult.QuoteChar, [rfReplaceAll]) + AResult.QuoteChar;
    AResult.DelimitedText := DelimitedText;

  finally

    AResult.Delimiter := SavedDelimiter;

    AResult.QuoteChar := SavedQuoteChar;

    AResult.StrictDelimiter := SavedStrictDel;

  end;

end;

Или так (если хочется руками и/или с множественными разделителями):

procedure Tokenize(const ASource, ADelimiters: String; const AResult: TStrings);

var

  CutPos: Integer;

  Src, Line: String;

begin

  if ASource = '' then

    Exit;
  AResult.BeginUpdate;

  try

    Src := ASource;

    AResult.Clear;

    repeat
      CutPos := LastDelimiter(ADelimiters, Src);

      if CutPos > 0 then

      begin

        Line := Copy(Src, CutPos + 1, MaxInt);

        Src := Copy(Src, 1, CutPos - 1);

      end

      else

      begin

        Line := Src;

        Src := '';

      end;
      AResult.Insert(0, Line);
    until Src = '';

  finally

    AResult.EndUpdate;

  end;

end;

Пример использования:

Tokenize('Test 1;Test 2;Test 3', ';', Memo1.Lines);

или:

var

  SL: TStringList;

begin

  SL := TStringList.Create;

  try

    Tokenize('Test 1;Test 2;Test 3', ';', SL);

    // что-то делаем с SL

  finally

    FreeAndNil(SL);

  end;

end;

тема на форуме