Графический ListBox

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    ListBox1: TListBox;
    Button1: TButton;
    OpenDialog1: TOpenDialog;
    procedure FormCreate(Sender: TObject);
    procedure ListBox1DrawItem(Control: TWinControl; Index: Integer;
      Rect: TRect; State: TOwnerDrawState);
    procedure ListBox1MeasureItem(Control: TWinControl; Index: Integer;
      var Height: Integer);
    procedure Button1Click(Sender: TObject);
  private
    FImgList: TImageList;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
  ShellAPI, ImgList;

function GetIconIndex(const FileName: string): Integer;
var
  FileInfo: TSHFileInfo;
begin
  SHGetFileInfo(PChar(FileName), 0, FileInfo, SizeOf(FileInfo), SHGFI_SYSICONINDEX);
  Result := FileInfo.iIcon;
end;

function GetSysImgListHandle: THandle;
var
  FileInfo: TSHFileInfo;
begin
  Result := SHGetFileInfo(nil, 0, FileInfo, SizeOf(FileInfo),
    SHGFI_SYSICONINDEX or SHGFI_LARGEICON);
end;  

procedure TForm1.FormCreate(Sender: TObject);
begin
  FImgList := TImageList.Create(Self);
  FImgList.Handle := GetSysImgListHandle;
  FImgList.DrawingStyle := dsTransparent;
  FImgList.ShareImages := True;
  ListBox1.Style := lbOwnerDrawVariable;
end;

procedure TForm1.ListBox1DrawItem(Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);
var
  S: string;
  LB: TListBox;
begin
  LB := TListBox(Control);
  S := LB.Items[Index];
  with LB.Canvas do
  begin
    FillRect(Rect);
    with Rect do
    begin
      FImgList.Draw(LB.Canvas, Left + 1, Top + 1, GetIconIndex(S));
      TextOut(Left + FImgList.Width + 5, Top + (Bottom - Top - TextHeight(S)) div 2, S);
    end;
    if odFocused in State then
      DrawFocusRect(Rect);
  end;
end;

procedure TForm1.ListBox1MeasureItem(Control: TWinControl; Index: Integer;
  var Height: Integer);
begin
  Height := FImgList.Height + 2;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  with OpenDialog1 do
    if Execute then
      ListBox1.Items.Add(FileName);
end;

end.