Задержка в сотых долях секунды на BAT-файлах

Posted by obzor under Windows, Администрирование ОС, Архив, Пост-обзор

Стандартной команды задержки, типа sleep, в языке сценариев Windows не предусмотрено. Есть множество различных извращенных способов получить хоть какую-то задержку, например, через ping. Как сделать более точную задержку?

Arigato

Предлагаю более точный способ задержки, использующий счетчик времени %time%, который позволяет производить замеры времени с точностью до сотых долей секунды.

Код, реализующий задержку в 10 секунд:

@ echo off

:: Задержка в 10 секунд
echo %time%
echo Wait 10 seconds...
call :sleep 1000
echo %time%
pause
exit /b

:sleep
:: Относительно точная пауза в сотых доля секунды
setlocal
call :gettick
set /a finish=%errorlevel%+%1
if %finish% geq 8640000 set finish=0
:slplabel
call :gettick
if %errorlevel% lss %finish% goto slplabel
endlocal & exit /b

:gettick
:: Количество сотых долей секунды, прошедших с начала дня
setlocal
for /f "tokens=1-4 delims=:," %%a in ("%time%") do (
	set h=%%a
	set m=%%b
	set s=%%c
	set ms=%%d
)
set /a tick=ms+s*100+m*6000+h*360000
endlocal & exit /b %tick%

Задержка реализована в виде подпрограммы :sleep, получающей единственный параметр — продолжительность задержки в сотых долях секунды. Точность задержки не идеальная, но весьма неплохая. Единственны косяк может возникнуть в момент перехода времени с 23:59 на 00:00.

тема на форуме

Похожие статьи

• CMD скрипт, запустить из memo
• Массовая замена оригиналов фото копиями после сохранения в Photoshop
• Команды Cmd в консоли Delphi
• Чтение настроек из файла на CMD/BAT
• Чтение из буфера обмена результата cmd
• Перейти в самую новую папку с помощью BAT-файла
• Как на BAT-файлах проверить пуста ли папка
• Подсчет символов в строке ШЕЛ