Запуск сторонней программы с передачей строки и ожиданием ее завершения

uses
  Windows;

function CmdExec(const Cmd: string): Integer;
// Выполнение консольного приложения с ожиданием его завершения и возвратом кода возврата
var
  Rlst: LongBool;
  StartUpInfo: TStartUpInfo;
  ProcessInfo: TProcessInformation;
  ExitCode: Cardinal;
begin
  FillChar(StartUpInfo, SizeOf(TStartUpInfo), 0); // заполнение структуры нулями
  with StartUpInfo do
  begin
    cb := SizeOf(TStartUpInfo);
    dwFlags := STARTF_USESHOWWINDOW or STARTF_FORCEONFEEDBACK;
    wShowWindow := SW_SHOWNORMAL;
  end;
  Rlst := CreateProcess(
      nil,
      PChar(Cmd), // команда
      nil,
      nil,
      False, // флаг наследования текущего процесса
      NORMAL_PRIORITY_CLASS, // флаги способов создания процесса
      nil,
      nil, // текущий диск и каталог
      StartUpInfo, // структура STARTUPINFO
      ProcessInfo // структура PROCESS_INFORMATION
    );
  if Rlst then begin // если запуск прошел успешно
    with ProcessInfo do begin
      WaitForInputIdle(hProcess, INFINITE); // ждем завершения инициализации
      WaitForSingleObject(hProcess, INFINITE); // ждем завершения процесса
      GetExitCodeProcess(hProcess, ExitCode); // получаем код завершения
      CloseHandle(hThread); // закрываем дескриптор процесса
      CloseHandle(hProcess); // закрываем дескриптор потока
    end;
  end else begin // ошибка выполнения команды
    WriteLn('Error: ', GetLastError, ' > ', Cmd);
    ExitCode := 0;
  end;
  Result := Integer(ExitCode); // возвращаем код возврата с приведением к типу Integer
end;

var
  S: Integer;

begin
  S := CmdExec('program_b stroka');
  WriteLn(S);
  ReadLn;
end.