Как отключить js в webbrowser

Posted by maloy under Delphi

daa

Всем доброго времени суток!
Такой вопрос: возможно отключить яваскрипт в webbrowser, хочу сделать кнопку для включения\отключения скриптов.
Если можно пример кода.

Fahman

unit Unit1;

interface

uses
 Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, ActiveX,
 OleCtrls, SHDocVw, ExtCtrls, StdCtrls;
type
  TBrowser = class(TWebBrowser, IDispatch)
  protected
   function IDispatch.Invoke = Invoke;
   function Invoke(DispID: Integer; const IID: TGUID; LocaleID: Integer; Flags: Word; var Params; VarResult, ExcepInfo, ArgErr: Pointer): HResult; stdcall;
  public
   constructor Create(AOwner: TComponent); override;
  end;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Panel1: TPanel;
    procedure FormDestroy(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    WebBrowser: TWebBrowser;
  public
    { Public declarations }
  end;

var
 Form1: TForm1;

implementation

{$R *.dfm}

constructor TBrowser.Create(AOwner: TComponent);
begin
 inherited Create(AOwner);
end;

function TBrowser.Invoke(DispID: Integer; const IID: TGUID; LocaleID: Integer; Flags: Word; var Params; VarResult, ExcepInfo, ArgErr: Pointer): HResult;
const
 DISPID_AMBIENT_DLCONTROL=-5512;
 DLCTL_NO_SCRIPTS=$00000080;
begin
 if (Flags and DISPATCH_PROPERTYGET<>0) and (VarResult<>nil) then
 begin
  Result:=S_OK;
  if DispID = DISPID_AMBIENT_DLCONTROL then PVariant(VarResult)^:=Integer(DLCTL_NO_SCRIPTS)
  else Result:=DISP_E_MEMBERNOTFOUND;
 end
 else result:=inherited invoke(dispid, iid, localeid, flags, params, varresult, ExcepInfo, ArgErr);
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FreeAndNil(WebBrowser);
  if Button1.Tag = 1 then begin
    WebBrowser := TBrowser.Create(self);;
    Button1.Tag := 0;
    Button1.Caption := 'Включить JavaScript';
  end
  else begin
    WebBrowser := TWebBrowser.Create(self);
    Button1.Tag := 1;
    Button1.Caption := 'Отключить JavaScript';
  end;
  TControl(WebBrowser).Parent:=Panel1;
  WebBrowser.Align:=alclient;
  WebBrowser.Navigate('http://example.com/jscript.html'); // Тест
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
 WebBrowser.Free;
end;

end.

тема на форуме

Похожие статьи

• TWebBrowser, как сделать чтобы новые ссылки открывал в TabSheet