Поиск и копирование совпадений на нескольких листах

Posted by obzor under VBA

Как произвести копирование нескольких ячеек (наименование, кофицент, количество) из листа «Temp» на лист «Смета» только если значение ячейки «Temp».C#(наименование) найдено на листе «Прайс-лист».A:A (наименование)

Интересует пример макросом VBA, впр и индекс\поискпоз — не подходят…

• Temp — Лист с временными данными.
• Смета — лист где должны проводится расчеты
• Прайс лист — База номенклатуры по которой будет проводится расчет.

Aleksandr H.

Sub Macros()
    Dim sh As Worksheet, sh2 As Worksheet, sh3 As Worksheet
    Dim rng As Range, i As Long, j As Long, r As Long, sh2r As Long
    Set sh = Sheets("Temp")
    Set sh2 = Sheets("Прайс-Лист")
    Set sh3 = Sheets("Смета")
    ' строк в прайсе
    sh2r = sh2.Cells(sh2.Rows.Count, 1).End(xlUp).Row
    With sh
    ' перебираем елементы С на темпе
        For i = 2 To .Cells(.Rows.Count, 3).End(xlUp).Row
            ' сравниваем со списком листа Прайс-Лист
            For j = 1 To sh2r
                 ' найдено совпадение
                If sh2.Cells(j, "A") = .Cells(i, "C") Then
                ' последняя строка Сметы
                    r = sh3.Cells(sh3.Rows.Count, 1).End(xlUp).Row + 1
                    ' перенос значений на смету
                    .Range(.Cells(i, "C"), .Cells(i, "E")).Copy _
                            sh3.Cells(r, "A")
                    ' перенос цены на смету
                    sh3.Cells(r, "D") = sh2.Cells(j, "B")
                    ' выход из цикла
                    Exit For
                End If
            Next j
        Next
    End With
    Set sh = Nothing
    Set sh2 = Nothing
    Set sh3 = Nothing
End Sub

тема на форуме

Похожие статьи

• Ping из VBA
• Progress bar или индикация выполнения макроса в Microsoft Office Excel
• Запретить ввод пробелов в ячейки Excel
• Массовое переименование label на форме
• Вынести часть текста из многострочной ячейки по условию (Excel)
• Копирование данных в Excel «отталкиваясь» от последней заполненой строки
• Вставка данных в Excel после последней заполненной ячейки
• Как в Excel посчитать количество дней, прошедших с заданного числа
• Копирование данных «отталкиваясь» от последней заполненной строки Excel
• Как вытащить URL адрес из формулы с гиперссылкой в Excel