В тексте определить количество чисел, у которых три одинаковых цифры в числе

Posted by obzor under assembler

В тексте определить количество чисел, у которых три одинаковых цифры в числе (например, 36533).

Я думаю сделать так:
1) Раз это текст, то пусть числа вводятся с клавиатуры через пробел. И надо сделать цикл по выделению каждого слова (числа), ориентируясь на пробел как на признак конца слова. Чтобы работать с каждым словом, то бишь числом, отдельно.
2) Цикл, где считается количество вхождений каждого символа (то есть цифры) в слово. Если счетчик строго равен трем, то вывести это слово на экран.

R71MT

На FASM’е это дело можно организовать так. Мутновато.., но вроде работает.
Для корректного отображения — строку заканчивай пробелом:

org  100h
jmp  start

hello   db  13,10,'String: $'
bye     db  13,10,'Result: $'
string  db  80,0,80 dup(' ')     ;' входной буфер для dos(0Ah)
buff    db  20 dup('$')          ;' выходной буфер (место под каждое слово)
                                 ;' макс.длина слова: 20 символов
start:
;' Сохраняем строку юзера ========================================
   mov   ah,9               ;
   mov   dx,hello           ;
   int   21h                ;
   mov   ah,0Ah             ;
   mov   dx,string          ;
   int   21h                ;
   mov   ah,9               ;
   mov   dx,bye             ;
   int   21h                ;

;' Копируем очередное слово из строки в буфер ====================
   xor   ch,ch              ;' СН = текущая позиция в строке
   mov   cl,[string+1]      ;' CL = длина введённой строки
   mov   si,string+2        ;' указатель на начало строки
startCopy:                  ;
   mov   di,buff            ;' адрес приёмного буфера
   xor   bx,bx              ;' ВХ = 0 (это будет длина слова)
copy:                       ;
   lodsb                    ;' берём символы из SI,
   cmp   al,' '             ;'    ..пока не встретиться пробел
   je    stopCopy           ;
   stosb                    ;' запись их в DI.
   inc   bx                 ;' длина слова +1
   inc   ch                 ;' позиция в строке +1
   jmp   copy               ;' сл.символ...

;' Встретился пробел. Поиск триады в слове =======================
stopCopy:                   ;' в ВХ лежит длина слова
   push  si cx              ;' запомним текущую позицию в строке
   mov   si,buff            ;' SI = плавающий символ в слове
   mov   dx,bx              ;' СX/DX = длина слова
find3:                      ;
   mov   cx,bx              ;
   inc   cx                 ;' захватим последний символ
   xor   ah,ah              ;' AH будет флагом совпадений
   mov   di,buff            ;' где искать
   mov   al,byte[si]        ;' что искать
@@:                         ;' <----------------<<---------------+
   repne scasb              ;' ищем до совпадения!               |
   or    cl,cl              ;' все символы слова проверили?      |
   jz    test3              ;' да:  тест на 3                    |
   inc   ah                 ;' нет: флаг +1                      |
   jmp   @b                 ;' продолжаем поиск совпадений -->---+
test3:                      ;
   cmp   ah,3               ;' проверка флага на 3
   jz    stopFind           ;' прыг если равно
   inc   si                 ;' иначе: ищем сл.символ слова
   dec   dx                 ;' уменьшить длину слова
   jnz   find3              ;' конец слова? нет: искать дальше..
   jmp   clearBuff          ;' иначе: нет триады. Очистить буфер!

;' Есть 3 совпадения! Выводим результат ===========================
stopFind:
   mov   ah,9               ;' выводим слово из буфера
   mov   dx,buff            ;
   int   21h                ;
   mov   al,' '             ;' ..и вставляем пробел/разделитель
   int   29h                ;
clearBuff:                  ;' забиваем буфер баксами
   mov   al,'$'             ;
   mov   cx,20              ;
   mov   di,buff            ;
   rep   stosb              ;

;' Читаем следующее слово... ======================================
nextWord:                   ;
   pop   cx si              ;' восстанавливаем позицию в строке юзера
   cmp   ch,cl              ;' всю строку проверили?
   ja    exit               ;' да - на выход!
   jmp   startCopy          ;' иначе: берём сл.слово строки в буфер

exit:                       ;
   xor   ax,ax              ;
   int   16h                ;
   int   20h                ;' выход в DOS...

тема на форуме

Случайные статьи

• Определение активности программы
• Рассылка. Выпуск 180
• Удалить повторяющиеся элементы из массива (VBA в Excel)
• Движок поиска для самописного сайта
• Книга о физико-техническом моделировании
• Рассылка. Выпуск 253
• Перевод из строкового числа в численный
• Бинарные файлы и C#
• Фильтр списка ComboBox при вводе
• Как при вводе большого сообщения в MessageDlg перейти на новую строчку?